home *** CD-ROM | disk | FTP | other *** search
/ The Very Best of Atari Inside / The Very Best of Atari Inside 1.iso / mint / mntlib25 / _addsubd.cpp next >
Text File  |  1992-12-12  |  6KB  |  227 lines
  1. |
  2. | double floating point add/subtract routine
  3. |
  4. #ifndef __M68881__
  5.     .text
  6.     .even
  7.     .globl    __subdf3, ___subdf3
  8.     .globl    __adddf3, ___adddf3
  9. #ifndef    sfp004
  10. |
  11. | written by Kai-Uwe Bloem (I5110401@dbstu1.bitnet).
  12. | Based on a 80x86 floating point packet from comp.os.minix, written by P.Housel
  13. | patched by Olaf Flebbe (flebbe@tat.physik.uni-tuebingen.de)
  14. |
  15. | Revision 1.3.3 olaf 11-92 :
  16. |  + changed to get rid of rounding bits. a sticky register (d3) is
  17. |    sufficient. 
  18. | 
  19. | Revision 1.3.2 olaf 10-92 :
  20. |  + increased comparson by one again. (Dont understand, but it works)
  21. |  + corrected negation of rounding bits and mantissa
  22. |     >enquire now detects correct IEEE precision
  23. |     >paranoia now qualifies add/sub as correctly rounded
  24. |
  25. | Revision 1.3.1 olaf 10-92 :
  26. |  + increased comparison of exponents by one.
  27. |  + initialized sticky byte
  28. |  + corrected handling of rounding bits
  29. |     >paranoia now detects no SERIOUS DEFECTS any more
  30. |     ** Patches need _normdf Rev 1.6.1 (or higher) **
  31. |
  32. | Revision 1.3, kub 01-90 :
  33. | added support for denormalized numbers
  34. |
  35. | Revision 1.2, kub 01-90 :
  36. | replace far shifts by swaps to gain speed
  37. |
  38. | Revision 1.1, kub 12-89 :
  39. | Ported over to 68k assembler
  40. |
  41. | Revision 1.0:
  42. | original 8088 code from P.S.Housel
  43.  
  44. __subdf3:
  45. ___subdf3:
  46.     eorb    #0x80,sp@(12)    | reverse sign of v
  47. __adddf3:
  48. ___adddf3:
  49.     lea    sp@(4),a0    | pointer to u and v parameter
  50.     moveml    d2-d7,sp@-    | save registers
  51.     moveml    a0@,d4-d5/d6-d7    | d4-d5 = v, d6-d7 = u
  52.  
  53.     movel    d6,d0        | d0 = u.exp
  54.     swap    d0
  55.     movel    d6,d2        | d2.h = u.sign
  56.     movew    d0,d2
  57.     lsrw    #4,d0
  58.     andw    #0x07ff,d0    | kill sign bit
  59.  
  60.     movel    d4,d1        | d1 = v.exp
  61.     swap    d1
  62.     eorw    d1,d2        | d2.l = u.sign ^ v.sign
  63.     lsrw    #4,d1
  64.     andw    #0x07ff,d1    | kill sign bit
  65.  
  66.     andl    #0x0fffff,d6    | remove exponent from u.mantissa
  67.     tstw    d0        | check for zero exponent - no leading "1"
  68.     beq    0f
  69.     orl    #0x100000,d6    | restore implied leading "1"
  70.     bra    1f
  71. 0:    addw    #1,d0        | "normalize" exponent
  72. 1:
  73.     andl    #0x0fffff,d4    | remove exponent from v.mantissa
  74.     tstw    d1        | check for zero exponent - no leading "1"
  75.     beq    0f
  76.     orl    #0x100000,d4    | restore implied leading "1"
  77.     bra    1f
  78. 0:    addw    #1,d1        | "normalize" exponent
  79. 1:
  80.     clrl    d3        | init sticky register
  81.     negw    d1        | d1 = u.exp - v.exp
  82.     addw    d0,d1
  83.     beq    5f        | exponents are equal - no shifting neccessary
  84.     bgt    1f        | not equal but no exchange neccessary
  85.     exg    d4,d6        | exchange u and v
  86.     exg    d5,d7
  87.     subw    d1,d0        | d0 = u.exp - (u.exp - v.exp) = v.exp
  88.     negw    d1
  89.     tstw    d2        | d2.h = u.sign ^ (u.sign ^ v.sign) = v.sign
  90.     bpl    1f
  91.     bchg    #31,d2
  92. 1:
  93.     cmpw    #55,d1        | is u so much bigger that v is not
  94.     bge    7f        | significant ?
  95. |
  96. | shift mantissa left two digits, to allow cancellation of
  97. | most significant digit, while gaining an additional digit for
  98. | rounding.
  99. |
  100.     moveql  #1,d3    
  101. 2:    addl    d7,d7
  102.     addxl    d6,d6
  103.     subw    #1,d0        | decrement exponent
  104.     subw    #1,d1        | decrement counter
  105.     dbeq    d3,2b
  106.     clrl    d3
  107. |
  108. | now shift other mantissa right as fast as possible (almost).
  109. |
  110. 3:    
  111.     cmpw    #16,d1        | see if fast rotate possible
  112.     blt    4f
  113.     orw    d5,d3        | set sticky word
  114.     movew    d4,d5        | rotate by swapping register halfs
  115.     swap    d5
  116.     clrw    d4
  117.     swap    d4
  118.     subw    #16,d1
  119.     bra    3b
  120.  
  121. 0:    moveb   d5,d2        | use d2.b as scratch
  122.     andb    #1,d2        | test if 1 is shifted out
  123.     orb    d2,d3        | and put it in sticky 
  124.     lsrl    #1,d4        | shift v.mant right the rest of the way
  125.     roxrl    #1,d5        | to line it up with u.mant
  126. 4:    dbra    d1,0b        | loop
  127.     
  128. 5:
  129.     tstw    d2        | are the signs equal ?
  130.     bpl    6f        | yes, no negate necessary
  131. |
  132. | negate secand mantissa. One has to check the sticky word in order
  133. | to correct the twos complement.
  134. |
  135.     tstw    d3        | 
  136.     beq     9f        | No cerrection necessary
  137.     clrl    d1
  138.     addql   #1,d5
  139.     addxl   d1,d4
  140. 9:    negl    d5
  141.     negxl    d4
  142.         
  143. 6:
  144.     addl    d5,d7        | u.mant = u.mant + v.mant
  145.     addxl    d4,d6
  146.     bcs    7f        | need not negate
  147.     tstw    d2        | opposite signs ?
  148.     bpl    7f        | do not need to negate result
  149.  
  150.     negl    d7
  151.     negxl    d6
  152.     notl    d2        |     switch sign
  153. 7:
  154.     movel    d6,d4        | move result for normalization
  155.     movel    d7,d5
  156.     clrl    d1
  157.     tstl    d3
  158.     beq     8f
  159.     moveql   #-1,d1
  160. 8:    swap    d2        | put sign into d2 (exponent is in d0)
  161.     jmp    norm_df        | leave registers on stack for norm_df
  162. #else    sfp004
  163. | double precision floating point stuff for Atari-gcc using the SFP004
  164. | developed with gas
  165. |
  166. | double floating point add/subtract routine
  167. |
  168. | M. Ritzert (mjr at dmzrzu71)
  169. |
  170. | 4.10.1990
  171. |
  172. | no NAN checking implemented since the 68881 treats this situation "correct",
  173. | i.e. according to IEEE
  174.  
  175. | addresses of the 68881 data port. This choice is fastest when much data is
  176. | transferred between the two processors.
  177.  
  178. comm =     -6
  179. resp =    -16
  180. zahl =      0
  181.  
  182. | waiting loop ...
  183. |
  184. | wait:
  185. | ww:    cmpiw    #0x8900,a0@(resp)
  186. |     beq    ww
  187. | is coded directly by
  188. |    .long    0x0c688900, 0xfff067f8
  189.  
  190. __subdf3:
  191. ___subdf3:
  192. | double precision subtraction
  193. | sub second arg from fp0
  194.     lea    0xfffffa50:w,a0
  195.     movew    #0x5400,a0@(comm)    | load first argument to fp0
  196.     cmpiw    #0x8900,a0@(resp)    | check
  197.     movel    a7@(4),a0@
  198.     movel    a7@(8),a0@
  199.     movew    #0x5428,a0@(comm)
  200.     .long    0x0c688900, 0xfff067f8
  201.     movel    a7@(12),a0@
  202.     movel    a7@(16),a0@
  203.     movew    #0x7400,a0@(comm)    | result to d0/d1
  204.     .long    0x0c688900, 0xfff067f8
  205.     movel    a0@,d0
  206.     movel    a0@,d1
  207.      rts
  208.  
  209. __adddf3:
  210. ___adddf3:
  211.     lea    0xfffffa50:w,a0
  212.     movew    #0x5400,a0@(comm)        | load fp0
  213.     cmpiw    #0x8900,a0@(resp)        | got it?
  214.     movel    a7@(4),a0@            | take a hi from stack to FPU
  215.     movel    a7@(8),a0@            | take a lo from stack to FPU
  216.     movew    #0x5422,a0@(comm)        | add second arg to fp0
  217.     .long    0x0c688900, 0xfff067f8
  218.     movel    a7@(12),a0@            | move b hi from stack to FPU
  219.     movel    a7@(16),a0@            | move b lo from stack to FPU
  220.     movew    #0x7400,a0@(comm)        | result to d0/d1
  221.     .long    0x0c688900, 0xfff067f8
  222.     movel    a0@,d0                | download result
  223.     movel    a0@,d1                | download result
  224.      rts
  225. #endif    sfp004
  226. #endif    __M68881__
  227.